Huge script change. Reformatting of the disk_config_configuration function.

2025-12-11 08:50:37 +01:00
parent 1f8c6c50d7
commit 0e0ed4d3a3
9 changed files with 138 additions and 183 deletions
@@ -0,0 +1,50 @@
+{ config, lib, ... }:
+
+# --> SnapRAID disks research
+let
+  contentDiskMounts = lib.attrsets.attrNames (
+    lib.attrsets.filterAttrs (name: value: lib.strings.hasPrefix "/mnt/content-" name) config.fileSystems
+  );
+  parityDiskMounts = lib.attrsets.attrNames (
+    lib.attrsets.filterAttrs (name: value: lib.strings.hasPrefix "/mnt/parity-" name) config.fileSystems
+  );
+  snapraidDataDisks = lib.lists.foldl'
+    (acc: path: acc // { "d${toString (acc.i + 1)}" = path; i = acc.i + 1; })
+    { i = 0; }
+    contentDiskMounts;
+in
+# SnapRAID disks research <--
+
+
+
+# --> MergerFS setup
+{
+  fileSystems."/mnt/data-storage" = {
+    device = "mergerfs";
+    fsType = "fuse";
+    options = [
+      "defaults"
+      "allow_other"
+      "use_ino"
+      "cache.files=off"
+      "moveonenospc=true"
+      "category.create=mfs"
+      "srcmounts=${lib.strings.concatStringsSep ":" contentDiskMounts}"
+    ];
+  };
+# MergerFS setup <--
+
+
+
+# --> SnapRAID setup
+  services.snapraid = {
+    enable = true;
+    contentFiles = map (disk: "${disk}/snapraid.content") contentDiskMounts;
+    parityFiles = map (disk: "${disk}/snapraid.parity") parityDiskMounts;
+    dataDisks = builtins.removeAttrs snapraidDataDisks [ "i" ];
+  };
+# SnapRAID setup <--
+
+
+
+}