Migrated from multi repos to monorepo architecture.

2026-05-02 12:52:08 +02:00
parent 72668492f5
commit 73adb395c0
218 changed files with 9639 additions and 57 deletions
@@ -0,0 +1,74 @@
+{
+  description = "Numbus - Simplified NixOS deployments";
+
+  inputs = {
+    # Nix unstable packages
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
+    # Nix stable packages
+    nixpkgs-stable.url = "github:nixos/nixpkgs/nixos-25.11";
+    # Numbus
+    numbus.url = "https://gittea.dev/numbus/numbus";
+    # Disko
+    disko.url = "github:nix-community/disko";
+    disko.inputs.nixpkgs.follows = "nixpkgs";
+    # Sops-nix
+    sops-nix.url = "github:Mic92/sops-nix";
+    sops-nix.inputs.nixpkgs.follows = "nixpkgs";
+    # Flatpaks
+    nix-flatpak.url = "github:gmodena/nix-flatpak";
+  };
+
+  outputs = { self, nixpkgs, ... }@inputs: 
+    let
+      system = "x86_64-linux";
+      pkgs = nixpkgs.legacyPackages.${system};
+      
+      # Helper for defining systems
+      mkNumbus = { deviceModule, extraModules ? [], nixpkgsRef, deviceType }: nixpkgsRef.lib.nixosSystem {
+        inherit system;
+        specialArgs = { inherit inputs deviceType; };
+        modules = [
+          inputs.disko.nixosModules.disko
+          inputs.sops-nix.nixosModules.sops
+          self.nixosModules.common
+          deviceModule
+        ] ++ extraModules;
+      };
+    in {
+      nixosModules = {
+        common = ./modules/common;
+        server = ./modules/server;
+        backup = ./modules/backup;
+        computer = ./modules/computer;
+        tv = ./modules/tv;
+      };
+
+      nixosConfigurations = {
+        numbus-server = mkNumbus {
+          deviceModule = self.nixosModules.server;
+          nixpkgsRef = inputs.nixpkgs-stable;
+          deviceType = "server";
+        };
+
+        numbus-backup = mkNumbus {
+          deviceModule = self.nixosModules.backup;
+          nixpkgsRef = inputs.nixpkgs-stable;
+          deviceType = "backup";
+        };
+
+        numbus-computer = mkNumbus {
+          deviceModule = self.nixosModules.computer;
+          extraModules = [ inputs.nix-flatpak.nixosModules.nix-flatpak ];
+          nixpkgsRef = inputs.nixpkgs;
+          deviceType = "computer";
+        };
+
+        numbus-tv = mkNumbus {
+          deviceModule = self.nixosModules.tv;
+          nixpkgsRef = inputs.nixpkgs;
+          extraModules = [ inputs.nix-flatpak.nixosModules.nix-flatpak ];
+          deviceType = "tv";
+        };
+      };
+    };
+}