start: data_div_content
data_div_content: (file_section | working_storage | linkage)*
file_section: "FILE" "SECTION" DOT fd+
fd: "FD" NAME FD_SUFFIX data_item+
FD_SUFFIX: /(?:"[^"]*"|'[^']*'|[^.])*\./
working_storage: "WORKING-STORAGE" "SECTION" DOT data_item*
linkage: "LINKAGE" "SECTION" DOT data_item*
data_item: level_num (NAME | "FILLER") clause* DOT
level_num: LEVEL
clause: pic_clause | value_clause | occurs_clause | redefines_clause | usage_clause
      | "SYNC" | "SYNCHRONIZED"
      | "JUSTIFIED" "RIGHT"?
      | "BLANK" "WHEN" "ZERO"
      | "GLOBAL" | "EXTERNAL"
pic_clause: "PIC" "IS"? PICTURE_STRING
value_clause: "VALUE" "IS"? value_literal+
value_literal: INT | SIGNED_NUMBER | STRING | SQSTRING
             | "ZERO" | "ZEROS" | "ZEROES"
             | "SPACE" | "SPACES"
             | "HIGH-VALUE" | "HIGH-VALUES"
             | "LOW-VALUE" | "LOW-VALUES"
SQSTRING: /'[^']*'/
redefines_clause: "REDEFINES" NAME
occurs_clause: "OCCURS" INT "TIMES"? ("DEPENDING" "ON" NAME)?
usage_clause: USAGE_VAL
USAGE_VAL: "COMP" | "COMP-3" | "COMP-5" | "BINARY" | "PACKED-DECIMAL" | "DISPLAY"
LEVEL: /0[1-9]|[1-4][0-9]|49|77|88/
NAME: /[A-Z][A-Z0-9-]*/
PICTURE_STRING: /[0-9A-Z()+,\-*\/V]+/i
INT: /[0-9]+/
DOT: /\./
%import common.SIGNED_NUMBER
%import common.ESCAPED_STRING -> STRING
%import common.WS
%ignore WS